Report System Help

[Astram]

PHP Code:

//#CLIENTSIDE
function onPlayerChats() {
if (player.chat == "/report") {
Report_Window1.show();
  new GuiWindowCtrl("Report_Window1") {
    profile = GuiBlueWindowProfile;
    clientrelative = true;
    clientextent = "313,237";

    canclose = false;
    canmaximize = false;
    canminimize = false;
    canmove = true;
    canresize = true;
    closequery = false;
    destroyonhide = false;
    text = "Report System";
    x = 480;
    y = 159;

    new GuiTextEditCtrl("Report_TextEdit1") {
      profile = GuiBlueTextEditProfile;
      height = 20;
      text = "";
      width = 313;
      y = 45;
    }
    new GuiTextCtrl("Report_Text1") {
      profile = GuiBlueTextProfile;
      height = 20;
      text = "Use this system to report players who arent obeying the rules!";
      width = 301;
      x = 5;
    }
    new GuiTextCtrl("Report_Text2") {
      profile = GuiBlueTextProfile;
      height = 20;
      text = "Account Of Report";
      width = 91;
      x = 109;
      y = 26;
    }
    new GuiButtonCtrl("Report_Button1") {
      profile = GuiBlueButtonProfile;
      height = 17;
      text = "File Report";
      width = 155;
      y = 220;
    }
    new GuiButtonCtrl("Report_Button2") {
      profile = GuiBlueButtonProfile;
      height = 17;
      text = "Close";
      width = 159;
      x = 154;
      y = 220;
    }
    new GuiButtonCtrl("Report_Button3") {
      profile = GuiBlueButtonProfile;
      height = 19;
      text = "Load and Manage Reports";
      width = 191;
      x = 62;
      y = 201;
    }
    new GuiTextCtrl("Report_Text3") {
      profile = GuiBlueTextProfile;
      height = 20;
      text = "Reason To Report";
      width = 87;
      x = 108;
      y = 80;
    }
    new GuiTextEditCtrl("Report_TextEdit2") {
      profile = GuiBlueTextEditProfile;
      height = 20;
      text = "";
      width = 313;
      y = 113;
    }
  }
}
}

function Report_Button1.onAction() {
  player.chat = "Filed Report!";
  serverr.player = player.account;
  serverr.account = Report_TextEdit1.text;
  serverr.reason = Report_TextEdit2.text;
  Report_Window1.hide();
}

function Report_Button2.onAction() {
  Report_Window1.hide();
}

function Report_Button3.onAction() {
if (player.guild == "Owner") {
echo("Report System: "@serverr.player@" reported "@serverr.account@" for "@serverr.reason@"!");
}
} 


The Problem with this is that, I dont know how to send the text edit text, to the RC by pressing the file report button. Can someone please help?

[fowlplay4]

Originally Posted by cbk1994

Nope. You can trigger either way back and forth as much as you want. You can create an infinite loop if you want:

PHP Code:

function onActionServerSide(cmd) {
  if (cmd == "ping") {
    triggerClient("gui", this.name, "ping");
  }
}

//#CLIENTSIDE
function onCreated() {
  triggerServer("gui", this.name, "ping"); // start the loop
}

function onActionClientSide(cmd) {
  if (cmd == "ping") {
    this.counter ++;
    player.chat = "Pings: " @ this.counter;
    triggerServer("gui", this.name, "ping");
  }
} 


Though obviously you wouldn't want to do something like that in practical scripting

You can also trigger weapons of other players.

PHP Code:

function onActionServerSide(cmd, target, msg) {
  if (cmd == "tell") {
    temp.pl = findPlayerByCommunityName(target);
    
    if (pl == null) {
      return player.chat = "(player not found)";
    }
    
    pl.triggerClient("gui", this.name, "tell", player.communityname, msg);
  }
}

//#CLIENTSIDE
function onPlayerChats() {
  if (player.chat.starts("tell")) { // format is: tell account "message here"
    temp.tokens = player.chat.tokenize();
    
    temp.acc = tokens[1];
    temp.msg = tokens[2];
    
    triggerServer("gui", this.name, "tell", acc, msg);
  }
}

function onActionClientSide(cmd, sender, msg) {
  if (cmd == "tell") {
    player.chat = sender @ ": " @ msg;
  }
} 


To use this you would say: tell cbk1994 "Hi there ugly!"

That would trigger serverside, try to find a player with the community name 'cbk1994', and if found, trigger clientside on the same weapon for that player. Once it receives the trigger clientside, it would set my chat to 'Engine: Hi there ugly!'.

This is a bit of a silly example since you can set players' chat serverside, but it could be used, for example, if you have some kind of GUI window displaying the message.

and a popular function to send messages to people on rc chat...

sendtorc(msg)

[Astram]

That doesnt really help me, because that doesnt involve any GUIs

[fowlplay4]

Your problem isn't with GUIs though, you use triggerserver to send the data (I.e: Report_TextEdit2.text) Reason from the client to the server and display it to RC using sendtorc.

[Astram]

Originally Posted by fowlplay4

Your problem isn't with GUIs though, you use triggerserver to send the data (I.e: Report_TextEdit2.text) Reason from the client to the server and display it to RC using sendtorc.

triggerclient()?
This seriously confuses me... New towards scripting Dx

[fowlplay4]

Syntax: triggerserver(type, name, param, [...])

type - Depending on what you're doing this will usually be "gui" if you're using it in a weapon script. You can also trigger DB-NPCs by specifying "npc" instead.

name - Name of object to trigger, you'll most often be specifying the weapon/npc's name by using it's this.name value.

param - Short for parameter, this is the data you are sending to the server.

... - (Optional) You can specify as many additional parameters as you want, if you need more than 10 you probably need to re-think your approach.

Example: Sending a message to the server in a weapon script.

PHP Code:

// The function that is triggered by triggerserver
function onActionServerSide() {

  // The data from the triggerserver call is automatically placed into the 
  // params array.
  // It's stored like this:
  // params[0] = "message"
  // params[1] = "The actual message data"

  // Check if the first parameter is "message"
  // This is basically a minor security check, but also allows for more flexibility 
  // down the line if you send more than just messages to the server-side.
  if (params[0] == "message") {
    // Concates a message using the player's account and the
    // message data in params[1]
    temp.msg = player.account SPC "sent" SPC params[1];
    // Displays the message on RC
    sendtorc(temp.msg);
  }
}

//#CLIENTSIDE
function onCreated() {
  // Sends a trigger to the server-side portion of this script.
  // It also passes "message" and "The actual message data" as params.
  // On the server-side the parameter data is placed into a params array.
  triggerserver("gui", this.name, "message", "The actual message data");
}