[fowlplay4]

Okay then, No.

But the script isn't that long or complicated, is this what you're trying to accomplish?

PHP Code:

//#CLIENTSIDE

function onCreated() {
  // Player Attr Position to store Dimension in
  this.attrpos = 30;
  // Initialize Dimension
  setDim(0);
  // Begin Looping
  setTimer(0.05);
}

// Test Command for Changing Dimensions
// /dim dimension

function onPlayerChats() {
  if (player.chat.starts("/dim")) {
    setDim(player.chat.substring("/dim ".length()));
  }
}

// Dimension Accessor / Mutator

public function setDim(newdim) {
  this.dim = newdim;
  player.attr[this.attrpos] = newdim;
}

public function getDim() return this.dim;

// Loop to find and hide players in other dimensions..

function onTimeout() {
  for (temp.p: players) {
    // Ignore yourself
    if (temp.p == player) continue;
    // Determine Dimension
    temp.dimz = temp.p.attr[this.attrpos];
    // Check Dimension
    if (dimz != getDim()) {
      if (temp.p.x != -3) {
        // Record Old Position
        this.("pos_" @ temp.p.account) = {temp.p.x, temp.p.y};
      }
      // Hide Player
      temp.p.x = temp.p.y = -3;
    } else {
      // Player Offscreen?
      if (temp.p.x == -3) {
        // Restore them on the screen
        temp.oldpos = this.("pos_" @ temp.p.account);
        temp.p.x = temp.oldpos[0];
        temp.p.y = temp.oldpos[1];
      }
    }
  }
  setTimer(0.05);
} 


It's actually pretty cool, might even use it to hide from players while on Zodiac lol.

The only issue is that sometimes player's don't reappear in gmap environments because they are in a different level or something.