Graal Forums - Question box script

Graal Forums (https://forums.graalonline.com/forums/index.php)

- NPC Scripting (https://forums.graalonline.com/forums/forumdisplay.php?f=8)

- - Question box script (https://forums.graalonline.com/forums/showthread.php?t=134267522)

Question box script

Hey, i'm trying to make a question prompt that basically pops up with a question, this is in a class. So then if I want to ask the player a question I just join the NPC or weapon to the class and call the method.
I can't figure out how to get the answer back. In C# you do something like this. Here is the NPC.

PHP Code:


		
			
function onCreated(){

  temp.qu = AskQuestion("This is a title", "This is a question");

  if(qu){

    this.chat = "It's true!";

  }else{

    this.chat = "It's not true!";

  }

}

Here is the class.

PHP Code:


		
			
//#CLIENTSIDE

function AskQuestion(title, question) {

  new GuiWindowCtrl("QUESTION_WINDOW") {

    profile = GuiBlueWindowProfile;

    clientrelative = true;

    clientextent = "222,99";



    canclose = false;

    canmaximize = false;

    canminimize = false;

    canmove = true;

    canresize = true;

    closequery = false;

    destroyonhide = false;

    text = title;

    x = 1093;

    y = 646;



    new GuiButtonCtrl("QUESTION_YES") {

      profile = GuiBlueButtonProfile;

      text = "Yes";

      width = 116;

      y = 69;

    }

    new GuiButtonCtrl("QUESTION_NO") {

      profile = GuiBlueButtonProfile;

      text = "No";

      width = 107;

      x = 115;

      y = 69;

    }

    new GuiScrollCtrl("QUESTION_SCROLL") {

      profile = GuiBlueScrollProfile;

      height = 68;

      hscrollbar = "dynamic";

      vscrollbar = "dynamic";

      width = 225;



      new GuiMLTextCtrl("QUESTION_MULTILINE") {

        profile = GuiBlueMLTextProfile;

        height = 34;

        horizsizing = "width";

        text = question;

        width = 200;

      }

    }

  }

}

function QUESTION_YES.onAction() {

  QUESTION_WINDOW.destroy();

  return true;

}



function QUESTION_NO.onAction() {

  QUESTION_WINDOW.destroy();

  return false;

}

Cheers.

Try using scheduleevent() when they answer your question

So have AskQuestion(); then also have another function to get the results?

Exactly. I would use catchevent() to catch the button clicks on both buttons and send them to 1 method which would call the event.

You could probably do this, I commented the changes.

PHP Code:


		
			
function AskQuestion(title, question) {
  this.ans = false;
  
  new GuiWindowCtrl("QUESTION_WINDOW") {
    profile = GuiBlueWindowProfile;
    clientrelative = true;
    clientextent = "222,99";

    canclose = false;
    canmaximize = false;
    canminimize = false;
    canmove = true;
    canresize = true;
    closequery = false;
    destroyonhide = false;
    
    // added visible = true so it shows for new messages
    visible = true;
    text = title;
    x = 1093;
    y = 646;

    new GuiButtonCtrl("QUESTION_YES") {
      profile = GuiBlueButtonProfile;
      text = "Yes";
      width = 116;
      y = 69;
      
      // catch the buttonclick event and send it to onButtonClick
      thiso.catchEvent(this, "onAction", "onButtonClick");
    }
    new GuiButtonCtrl("QUESTION_NO") {
      profile = GuiBlueButtonProfile;
      text = "No";
      width = 107;
      x = 115;
      y = 69;
      
      // catching the buttonclick event and send it to onButtonClick
      thiso.catchEvent(this, "onAction", "onButtonClick");
    }
    new GuiScrollCtrl("QUESTION_SCROLL") {
      profile = GuiBlueScrollProfile;
      height = 68;
      hscrollbar = "dynamic";
      vscrollbar = "dynamic";
      width = 225;

      new GuiMLTextCtrl("QUESTION_MULTILINE") {
        profile = GuiBlueMLTextProfile;
        height = 34;
        horizsizing = "width";
        text = question;
        width = 200;
      }
    }
  }
  
  // wait until the window is hidden 
  waitfor(QUESTION_WINDOW, "onHide");

  return this.ans;
}

function onButtonClick(obj) {
  this.ans = obj.text != "No";
  QUESTION_WINDOW.hide();
}

Cheers Tig, wasn't even aware Graal had a waitfor method.