Graal Forums - Level transition fade in/out

Graal Forums (https://forums.graalonline.com/forums/index.php)

- NPC Scripting (https://forums.graalonline.com/forums/forumdisplay.php?f=8)

- - Level transition fade in/out (https://forums.graalonline.com/forums/showthread.php?t=134260559)

Level transition fade in/out

You probably went on Ruins lately, and saw the level transition effects (fade in/out). A lot of people are asking me how it was made, so I decided to simply share it. Might be useful for people later on!

Class (named level_link)

PHP Code:


		
			
function onCreated() {
  this.setshape(1, this.w*16, this.h*16);
  this.blockagain();
}

//#CLIENTSIDE
function onCreated() {
  this.setshape(1, this.w*16, this.h*16);
  this.blockagain();
}

function onPlayerTouchsMe() {
  if (this.touched) return;
  temp.data = {this.lvl, this.lvlx, this.lvly};
  interfaceVisuals.fadelevel(temp.data);
  this.touched = true;
  setTimer(3);
}

function onTimeout()
  this.touched = false;

interfaceVisuals is our wNPC handling all the visuals, along with the fade in/out effects, here are the bits of it for the fade effect

PHP Code:


		
			
public function fadelevel(lvldata) {
  client.freezed = true;
  fadeOut(lvldata);
}
  

function fadeIn() {
  for(temp.i = 1; temp.i >= -0.30; temp.i -= 0.30) {
    findimg(this.poly).alpha = temp.i;
    sleep(0.05);
  }
  hideimg(this.poly);
  this.poly = 0;
  client.freezed = false;
}

function fadeOut(lvldata) {
  temp.data = lvldata;
  client.warpdata = lvldata;
  if (this.poly == 0) this.poly = drawScreenPoly(); 
  for(temp.i = 0; temp.i < 1.35; temp.i += 0.35) {
    findimg(this.poly).alpha = temp.i;
    sleep(0.05);
  }
  setani("your idle gani name", 0);
  sleep(0.25);
  triggerserver("gui", "interfaceVisuals", "warpplayer", 0);
  sleep(0.5);
  fadeIn();
}

Here's an example of level npc you can use in order to use the link and level transition:

PHP Code:


		
			
this.join("level_link");
this.w = 6;
this.h = 1;
//#CLIENTSIDE
this.w = 6;
this.h = 1;
this.lvl = "level name it links to.nw";
this.lvlx = 24;
this.lvly = 1;

this.w is the link's width and this.h the link's height (in tiles of course)

Credits to Axel (account: Contrast, go +rep him if you want!) for making it, and to Tig who gave us some hints on how GK's was made. Enjoy :)

Please, please, please don't do this.

PHP Code:


		
			
this.join("level_link");
this.w = 6;
this.h = 1;
//#CLIENTSIDE
this.w = 6;
this.h = 1;
this.lvl = "level name it links to.nw";
this.lvlx = 24;
this.lvly = 1;

This is so much nicer and far preferable:

PHP Code:


		
			
function onCreated() {
  this.join("level_link");
  this.w = 6;
  this.h = 1;
}
//#CLIENTSIDE
function onCreated() {
  this.w = 6;
  this.h = 1;
  this.lvl = "level name it links to.nw";
  this.lvlx = 24;
  this.lvly = 1;
}

Also, your weapon script is extremely insecure. If that script is in use, I could easily warp to any level on Ruins with Cheat Engine. Heck, it's less secure than traditional links. The server should never accept data from the client (such as a level name).

I would probably do it like so (unimportant parts omitted):

PHP Code:


		
			
// link class
function onCreated() {
  // establish a way to refer to it via coordinates serverside
  this.level.link.(@ this.x  @ "_" @ this.y) = this;
}

//#CLIENTSIDE
function onPlayerTouchsMe() {
  // setup the x,y so the server can find the link
  interfaceVisuals.trigger("touchLevelLink", this);
}

and in the link weapon (fading bits omitted):

PHP Code:


		
			
function onActionServerSide(cmd, data) {
  if (cmd == "warp") {
    // find the relevant link
    temp.link = player.level.link.(@ data[0] @ "_" @ data[1]);
    
    if (link.lvl == null) {
      // level not defined
      return;
    }
    
    // check if the player's x/y are in the link
    if (! (player.x in |link.x, link.x + width|) || ! (player.y in |link.y, link.y + height|)) {
      return; // this might need some tweaking
    }
    
    player.setLevel2(link.lvl, link.warpx, link.warpy;
  }
}

//#CLIENTSIDE
function onTouchLevelLink(link) {
  // it's preferable to pass data as parameters rather than client. variables
  triggerServer("gui", this.name, "warp", {link.x, link.y});
}

Since the level data would be stored serverside instead of clientside there's no chance that the client can manipulate them to warp to any level except the level you've defined.

I didn't know about that, so I assume the custom level link could be revised. Thanks for pointing that out :)